> ## Documentation Index
> Fetch the complete documentation index at: https://private-7c7dfe99-mintlify-fbfa8bee.mintlify.site/llms.txt
> Use this file to discover all available pages before exploring further.

> Referencia para gestionar ClickPipes de forma programática con el proveedor de Terraform de ClickHouse.

# Referencia de Terraform para ClickPipes

Todos los tipos de ClickPipes se pueden crear y gestionar con el recurso `clickhouse_clickpipe` del [proveedor de Terraform de ClickHouse](https://registry.terraform.io/providers/ClickHouse/clickhouse/latest/docs/resources/clickpipe). Esta página describe la configuración del proveedor y ofrece ejemplos de configuración para cada tipo de ClickPipe compatible.

<div id="provider-setup">
  ## Configuración del proveedor
</div>

<Note>
  La compatibilidad con ClickPipes está disponible de forma general a partir de la versión del proveedor **v3.14.0**.
  Si utiliza una versión anterior, necesitará una versión alpha; consulte el
  [changelog del proveedor](https://github.com/ClickHouse/terraform-provider-clickhouse/releases)
  para obtener más información.
</Note>

Agregue el proveedor de ClickHouse a la configuración de Terraform:

```hcl theme={null}
terraform {
  required_providers {
    clickhouse = {
      source  = "ClickHouse/clickhouse"
      version = ">= 3.14.0"
    }
  }
}

provider "clickhouse" {
  organization_id = var.organization_id
  token_key       = var.token_key
  token_secret    = var.token_secret
}
```

Consulta [Gestión de claves de API](/es/products/cloud/features/admin-features/api/openapi) para ver instrucciones sobre cómo crear una clave de API para usarla con el proveedor.

<div id="resource-overview">
  ## Descripción general del recurso
</div>

El recurso `clickhouse_clickpipe` tiene los siguientes argumentos de nivel superior:

| Argumento        | Obligatorio | Descripción                                                                                       |
| ---------------- | ----------- | ------------------------------------------------------------------------------------------------- |
| `name`           | Sí          | Nombre del ClickPipe.                                                                             |
| `service_id`     | Sí          | ID del servicio de ClickHouse Cloud.                                                              |
| `source`         | Sí          | Configuración de la fuente (un bloque de fuente por ClickPipe).                                   |
| `destination`    | Sí          | Configuración del destino.                                                                        |
| `scaling`        | No          | Número y tamaño de las réplicas. El valor predeterminado es 1 réplica.                            |
| `field_mappings` | No          | Mapeos de campos personalizados entre las columnas de origen y de destino.                        |
| `settings`       | No          | Configuración avanzada de ClickPipe.                                                              |
| `stopped`        | No          | Establezca `true` para crear el ClickPipe en estado detenido. El valor predeterminado es `false`. |

Los atributos `id` y `state` son de solo lectura y ClickHouse Cloud los rellena después de la creación.

<div id="destination">
  ## Destino
</div>

El bloque `destination` es común a todos los tipos de fuente:

```hcl theme={null}
destination {
  database      = "default"           # Base de datos de destino. Por defecto es "default".
  table         = "my_table"          # Nombre de la tabla de destino. Obligatorio para todas las fuentes excepto CDC.
  managed_table = true                # Permite que ClickPipes cree y gestione la tabla. Por defecto es true.

  table_definition {
    engine {
      type      = "MergeTree"         # MergeTree, ReplacingMergeTree, SummingMergeTree o Null.
    }
    sorting_key   = ["id", "ts"]      # Opcional.
    partition_by  = "toYYYYMM(ts)"    # Opcional.
  }

  columns {
    name = "id"
    type = "UInt64"
  }

  columns {
    name = "message"
    type = "String"
  }
}
```

Para las fuentes de CDC (Postgres, MySQL, MongoDB, BigQuery), las tablas de destino se crean automáticamente a partir del esquema de la fuente; normalmente solo hace falta `database`.

<div id="examples">
  ## Ejemplos por tipo de ClickPipe
</div>

<div id="kafka">
  ### Kafka
</div>

Valores admitidos de `type`: `kafka`, `confluent`, `msk`, `azureeventhub`, `redpanda`, `warpstream`.

```hcl theme={null}
resource "clickhouse_clickpipe" "kafka_clickpipe" {
  name       = "My Kafka ClickPipe"
  service_id = var.service_id

  scaling {
    replicas               = 2
    replica_cpu_millicores = 250
    replica_memory_gb      = 1.0
  }

  source {
    kafka {
      type           = "confluent"
      format         = "JSONEachRow"
      brokers        = "broker.example.com:9092"
      topics         = "my_topic"
      consumer_group = "clickpipes-consumer-group"
      authentication = "PLAIN"

      credentials {
        username = "my_user"
        password = var.kafka_password
      }

      offset {
        strategy = "from_latest"
      }
    }
  }

  destination {
    table         = "my_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "message"
      type = "String"
    }

    columns {
      name = "timestamp"
      type = "DateTime"
    }
  }
}
```

<div id="kafka-schema-registry">
  #### Kafka con schema registry
</div>

```hcl theme={null}
resource "clickhouse_clickpipe" "kafka_avro_clickpipe" {
  name       = "My Kafka Avro ClickPipe"
  service_id = var.service_id

  source {
    kafka {
      type   = "confluent"
      format = "AvroConfluent"
      brokers = "broker.example.com:9092"
      topics  = "my_avro_topic"

      credentials {
        username = "my_user"
        password = var.kafka_password
      }

      schema_registry {
        url            = "https://schema-registry.example.com"
        authentication = "PLAIN"

        credentials {
          username = "sr_user"
          password = var.schema_registry_password
        }
      }
    }
  }

  destination {
    table         = "my_avro_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "event"
      type = "String"
    }
  }
}
```

<div id="kinesis">
  ### Amazon Kinesis
</div>

```hcl theme={null}
resource "clickhouse_clickpipe" "kinesis_clickpipe" {
  name       = "My Kinesis ClickPipe"
  service_id = var.service_id

  source {
    kinesis {
      format         = "JSONEachRow"
      stream_name    = "my-stream"
      region         = "us-east-1"
      iterator_type  = "TRIM_HORIZON"
      authentication = "IAM_USER"

      access_key {
        access_key_id = var.aws_access_key_id
        secret_key    = var.aws_secret_key
      }
    }
  }

  destination {
    table         = "my_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "message"
      type = "String"
    }
  }
}
```

<div id="kinesis-iam-role">
  #### Kinesis con rol de IAM
</div>

La autenticación mediante un rol de IAM requiere un servicio de ClickHouse en ejecución en AWS.

```hcl theme={null}
resource "clickhouse_clickpipe" "kinesis_iam_role_clickpipe" {
  name       = "My Kinesis ClickPipe (IAM Role)"
  service_id = var.service_id

  source {
    kinesis {
      format         = "JSONEachRow"
      stream_name    = "my-stream"
      region         = "us-east-1"
      iterator_type  = "LATEST"
      authentication = "IAM_ROLE"
      iam_role       = "arn:aws:iam::123456789012:role/my-kinesis-role"
    }
  }

  destination {
    table         = "my_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "message"
      type = "String"
    }
  }
}
```

<div id="s3">
  ### Amazon S3
</div>

```hcl theme={null}
resource "clickhouse_clickpipe" "s3_clickpipe" {
  name       = "My S3 ClickPipe"
  service_id = var.service_id

  source {
    object_storage {
      type           = "s3"
      url            = "https://my-bucket.s3.amazonaws.com/data/*.json"
      format         = "JSONEachRow"
      authentication = "IAM_USER"

      access_key {
        access_key_id = var.aws_access_key_id
        secret_key    = var.aws_secret_key
      }
    }
  }

  destination {
    table         = "my_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "message"
      type = "String"
    }
  }
}
```

<div id="s3-continuous">
  #### Ingestión continua de S3 con SQS
</div>

Para la ingestión continua con una cola de SQS (modo no ordenado). Consulta [Configuración del modo no ordenado](/es/integrations/clickpipes/object-storage/amazon-s3/unordered-mode) para ver las instrucciones de configuración.

```hcl theme={null}
resource "clickhouse_clickpipe" "s3_continuous_clickpipe" {
  name       = "My S3 Continuous ClickPipe"
  service_id = var.service_id

  source {
    object_storage {
      type           = "s3"
      url            = "https://my-bucket.s3.amazonaws.com/data/*.json"
      format         = "JSONEachRow"
      is_continuous  = true
      queue_url      = "https://sqs.us-east-1.amazonaws.com/123456789012/my-queue"
      authentication = "IAM_USER"

      access_key {
        access_key_id = var.aws_access_key_id
        secret_key    = var.aws_secret_key
      }
    }
  }

  destination {
    table         = "my_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "message"
      type = "String"
    }
  }
}
```

<div id="gcs">
  ### Google Cloud Storage
</div>

`service_account_key` debe ser el contenido codificado en base64 de un archivo de clave JSON de una cuenta de servicio de GCP.

```hcl theme={null}
resource "clickhouse_clickpipe" "gcs_clickpipe" {
  name       = "My GCS ClickPipe"
  service_id = var.service_id

  source {
    object_storage {
      type                = "gcs"
      url                 = "gs://my-bucket/data/*.json"
      format              = "JSONEachRow"
      authentication      = "SERVICE_ACCOUNT"
      service_account_key = var.gcs_service_account_key
    }
  }

  destination {
    table         = "my_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "message"
      type = "String"
    }
  }
}
```

<div id="abs">
  ### Azure Blob Storage
</div>

```hcl theme={null}
resource "clickhouse_clickpipe" "abs_clickpipe" {
  name       = "My Azure Blob ClickPipe"
  service_id = var.service_id

  source {
    object_storage {
      type                 = "azureblobstorage"
      azure_container_name = "my-container"
      path                 = "data/*.json"
      format               = "JSONEachRow"
      authentication       = "CONNECTION_STRING"
      connection_string    = var.azure_connection_string
    }
  }

  destination {
    table         = "my_table"
    managed_table = true

    table_definition {
      engine {
        type = "MergeTree"
      }
    }

    columns {
      name = "id"
      type = "UInt64"
    }

    columns {
      name = "message"
      type = "String"
    }
  }
}
```

<div id="postgres">
  ### Postgres CDC
</div>

```hcl theme={null}
resource "clickhouse_clickpipe" "postgres_cdc_clickpipe" {
  name       = "My Postgres CDC ClickPipe"
  service_id = var.service_id

  source {
    postgres {
      host     = "postgres.example.com"
      port     = 5432
      database = "mydb"

      credentials {
        username = "postgres_user"
        password = var.postgres_password
      }

      settings {
        replication_mode = "cdc"

        # Configuración opcional
        sync_interval_seconds              = 60
        pull_batch_size                    = 100000
        allow_nullable_columns             = true
        initial_load_parallelism           = 4
        snapshot_num_rows_per_partition    = 100000
        snapshot_number_of_parallel_tables = 1
      }

      table_mappings {
        source_schema_name = "public"
        source_table       = "users"
        target_table       = "public_users"
      }

      table_mappings {
        source_schema_name = "public"
        source_table       = "orders"
        target_table       = "public_orders"

        # Opcional
        excluded_columns       = ["internal_notes"]
        use_custom_sorting_key = true
        sorting_keys           = ["id", "created_at"]
        table_engine           = "ReplacingMergeTree"
      }
    }
  }

  destination {
    database = "default"
  }
}
```

<div id="postgres-iam-role">
  #### Postgres con rol de IAM
</div>

La autenticación mediante rol de IAM requiere un servicio de ClickHouse que se ejecute en AWS.

```hcl theme={null}
resource "clickhouse_clickpipe" "postgres_iam_role_clickpipe" {
  name       = "My Postgres CDC ClickPipe (IAM Role)"
  service_id = var.service_id

  source {
    postgres {
      host           = "mydb.cluster.us-east-1.rds.amazonaws.com"
      port           = 5432
      database       = "mydb"
      type           = "rdspostgres"
      authentication = "iam_role"
      iam_role       = "arn:aws:iam::123456789012:role/my-rds-role"

      credentials {
        username = "postgres_user"
      }

      settings {
        replication_mode = "cdc"
      }

      table_mappings {
        source_schema_name = "public"
        source_table       = "orders"
        target_table       = "public_orders"
      }
    }
  }

  destination {
    database = "default"
  }
}
```

<div id="mysql">
  ### CDC de MySQL
</div>

```hcl theme={null}
resource "clickhouse_clickpipe" "mysql_cdc_clickpipe" {
  name       = "My MySQL CDC ClickPipe"
  service_id = var.service_id

  source {
    mysql {
      host = "mysql.example.com"
      port = 3306
      type = "mysql"

      credentials {
        username = "mysql_user"
        password = var.mysql_password
      }

      settings {
        replication_mode = "cdc"

        # Configuración opcional
        sync_interval_seconds              = 30
        pull_batch_size                    = 10000
        allow_nullable_columns             = true
        initial_load_parallelism           = 4
        snapshot_num_rows_per_partition    = 100000
        snapshot_number_of_parallel_tables = 2
      }

      table_mappings {
        source_schema_name = "mydb"
        source_table       = "orders"
        target_table       = "mydb_orders"
      }

      table_mappings {
        source_schema_name = "mydb"
        source_table       = "customers"
        target_table       = "mydb_customers"

        # Opcional
        excluded_columns       = ["password_hash"]
        use_custom_sorting_key = true
        sorting_keys           = ["id"]
        table_engine           = "ReplacingMergeTree"
      }
    }
  }

  destination {
    database = "default"
  }
}
```

<div id="mongodb">
  ### CDC de MongoDB
</div>

```hcl theme={null}
resource "clickhouse_clickpipe" "mongodb_cdc_clickpipe" {
  name       = "My MongoDB CDC ClickPipe"
  service_id = var.service_id

  source {
    mongodb {
      uri             = "mongodb+srv://cluster0.example.mongodb.net"
      read_preference = "secondaryPreferred"

      credentials {
        username = "mongo_user"
        password = var.mongodb_password
      }

      settings {
        replication_mode = "cdc"

        # Configuraciones opcionales
        sync_interval_seconds              = 30
        pull_batch_size                    = 500
        snapshot_num_rows_per_partition    = 100000
        snapshot_number_of_parallel_tables = 2
      }

      table_mappings {
        source_database_name = "mydb"
        source_collection    = "users"
        target_table         = "mydb_users"
      }

      table_mappings {
        source_database_name = "mydb"
        source_collection    = "orders"
        target_table         = "mydb_orders"
        table_engine         = "ReplacingMergeTree"
      }
    }
  }

  destination {
    database = "default"
  }
}
```

<div id="bigquery">
  ### BigQuery
</div>

`service_account_file` debe ser el contenido codificado en base64 de un archivo JSON de clave de una cuenta de servicio de GCP.

```hcl theme={null}
resource "clickhouse_clickpipe" "bigquery_snapshot_clickpipe" {
  name       = "My BigQuery ClickPipe"
  service_id = var.service_id

  source {
    bigquery {
      snapshot_staging_path = "gs://my-staging-bucket/staging/"

      credentials {
        service_account_file = var.gcp_service_account_key
      }

      settings {
        replication_mode = "snapshot"

        # Configuraciones opcionales
        initial_load_parallelism           = 4
        snapshot_num_rows_per_partition    = 100000
        snapshot_number_of_parallel_tables = 2
        allow_nullable_columns             = true
      }

      table_mappings {
        source_dataset_name = "my_dataset"
        source_table        = "my_table"
        target_table        = "my_bigquery_table"
      }

      table_mappings {
        source_dataset_name    = "my_dataset"
        source_table           = "another_table"
        target_table           = "another_bigquery_table"
        table_engine           = "ReplacingMergeTree"
        use_custom_sorting_key = true
        sorting_keys           = ["id"]
        excluded_columns       = ["internal_col"]
      }
    }
  }

  destination {
    database = "default"
  }
}
```

<div id="scaling">
  ## Escalado
</div>

Todos los tipos de ClickPipe admiten el bloque `scaling` para configurar el número de réplicas y la asignación de recursos:

```hcl theme={null}
scaling {
  replicas               = 2     # Predeterminado: 1. Máximo: 10.
  replica_cpu_millicores = 500   # Entre 125 y 2000.
  replica_memory_gb      = 2.0   # Entre 0.5 y 8.0.
}
```

<div id="import">
  ## Importación de ClickPipes existentes
</div>

Los ClickPipes existentes pueden importarse al estado de Terraform mediante el ID del servicio y el ID del ClickPipe:

```bash theme={null}
terraform import clickhouse_clickpipe.example <service_id>:<clickpipe_id>
```